ethereum/solidity

@qq5678: TLDR the syntax is __address_to__.transfer(__amount__) where __address_to__ is the address to send funds, and __amount__ is the amount in Wei to send.

Here's an example for demonstrating how to deposit and withdraw from a smart contract;

Account.sol

// SPDX-License-Identifier: AGPL-3.0
pragma solidity 0.8.7;

/// @title Example contract for holding and distributing funds
/// @author S0AndS0
contract Account {
    address payable public owner;
    uint256 public balance;

    ///
    constructor(address payable _owner) payable {
        owner = _owner;
        balance = msg.value;
    }

    ///
    function deposit() external payable {
        balance += msg.value;
    }

    ///
    function withdraw(uint256 _amount) external {
        require(msg.sender == owner, "Message sender not contract owner");
        require(_amount <= balance, "Insufficient funds for withdraw");
        owner.transfer(_amount);
        balance -= _amount;
    }
}

And for completeness here's an example of how to initialize, and pay, a smart contract from a separate factory contract... plus a few bonus features;

Bank.sol

// SPDX-License-Identifier: AGPL-3.0
pragma solidity 0.8.7;

/// @title Example factory for making new accounts and getting initialized accounts
/// @author S0AndS0
contract Bank {
    /* Account.owner to address(Account) */
    mapping(address => address) accounts;

    ///
    function initializeAccount(address payable _account_owner)
        external
        payable
        returns (Account)
    {
        require(
            accounts[_account_owner] == address(0x0),
            "Account already initalized"
        );

        Account _account = (new Account){ value: msg.value }(_account_owner);
        accounts[_account_owner] = address(_account);
        return _account;
    }

    ///
    function getAccount(address _account_owner)
        external
        view
        returns (Account)
    {
        address _account_reference = accounts[_account_owner];
        require(_account_reference != address(0x0), "Account not initalized");
        return Account(_account_reference);
    }
}