red/help

For help with your code, suggestions and ideas, and learning Red.

Vladimir Vasilyev

@9214

@GiuseppeChillemi can you reformulate your question once again?

nedzadarek

@nedzadarek

@GiuseppeChillemi
When you set words to some values, <word>: <value> (e.g. the-answer: 42). <value> will be evaluated.

integer! (e.g. 42) will give you 42 (the value looks the same).
float! (e.g. 3.14) will give you 3.14
string!, pair! (2x14) and some more - like above

There are some "special" cases:

path! (e.g. foo/4) will be evaluated. For example you have foo: [1 2 3 4], when you set value to some word, val: foo/4, path foo/4 will be evaluated. foo/4 will be changed, in this case, to the 4th value of the foo (4).
lit-path! (e.g. 'foo/4) will be evaluated to path! foo/4. As you know already, you can get or reduce it. w: foo/4 and get w will give you 4 (4th element of the foo).
get-path! will get you value that it points to. It is like path!. However with path! you cannot get function!s for example (funs: #() funs/not-fibo: func [a] [ a - 10], funs/not-fibowill try to call not-fibo in the funs map, it will raise an error because you haven't provided an argument). You can get such value by using lit-path!: my-fun: :funs/not-fibo. After this you can call it like any other function: my-fun 12

block! every value within a block will be "the same", it won't use "special" rules that govern path!, lit-path! and get-path!. For example you have a block my-block: [42 3.14 "string" word :get-word 'lit-word set-word: [another block with a word]], you can see that *-path are not evaluated:
Helper:

foreach element my-block [
  print "Value: "
  probe element

  print "Type: "
  print mold type? element

  print "####"
  ]

Output:

Value: 
42
Type: 
integer!
####
Value: 
3.14
Type: 
float!
####
Value: 
"string"
Type: 
string!
####
Value: 
word
Type: 
word!
####
Value: 
:get-word
Type: 
get-word!
####
Value: 
'lit-word
Type: 
lit-word!
####
Value: 
set-word:
Type: 
set-word!
####
Value: 
[another block with a word]
Type: 
block!
####

And last value [another block with a word] will not evaluate words inside (you have no errors because there is no another and a word defined).

btw. tested on Red for Windows version 0.6.3 built 26-Mar-2018/1:14:22+02:00

Vladimir Vasilyev

@9214

@GiuseppeChillemi, @meijeru extensively documented evaluation rules here, if that's what you're interested in.

lepinekong

@lepinekong_twitter

Would it be easy to create a mathematical animation like this in red :)
https://i.imgur.com/IOJSlj0.jpg
https://www.youtube.com/watch?v=-X49VQgi86E

GiuseppeChillemi

@GiuseppeChillemi

@9214 , long day off work, I'll look at your exolaniotion this night or Tomorrow Morning

Giuseppe Chillemi

@GiuseppeChillemi_gitlab

@nedzadarek
Maybe yesterday we were after midnight but my question was different:
This is your code:

foo: [bar [baz 42]]
w: 'foo/bar/baz
get w
; == 42
reduce w
; == 42

I need something like:

z: bar
foo: [bar [baz 42]]
w: 'foo/(z)/baz
get w
; == 42
reduce w
; == 42

(I am just closing my day at work, I'll read it later)

Vladimir Vasilyev

@9214

@GiuseppeChillemi_gitlab perhaps you meant z: 'bar. Aside from that your example already works as you want.

Giuseppe Chillemi

@GiuseppeChillemi_gitlab

Yes ! z: 'bar

So if I write: z: 25, the whole path will be reduced to 'foo/25/'bar

Vladimir Vasilyev

@9214

>> append pick foo: append/only/dup [] [] 25 25 [bar yes]
== [bar yes]
>> z: 25
== 25
>> path: 'foo/(z)/bar
== foo/(z)/bar
>> reduce path
== yes

GiuseppeChillemi

@GiuseppeChillemi

@9214
I correct myself:
This does not work:

w: 'FOO/(:REDUCES-TO-BAR)/BAZ

This works:

first reduce reduce [w]

(Talking about REBOL2)

Chris Prinos

@cprinos

follow up to an earlier question on storing/manipulating functions in series...
with this code:

a: function [x] [x + 1]
b: function [x] [x * 2]
c: function [x] [x * x]

funcs:  reduce [:a :b :c]

foreach f funcs [ probe f 5]
foreach f funcs [ print f 5]
foreach f funcs [ print type? f 5]

I get different results via the interpreter red test.red vs compiled red -c -o test test.red

output with the interpreter:

6
10
25
6
10
25
integer
integer
integer

and with the compiled version:

func [x][x + 1]
func [x][x * 2]
func [x][x * x]
?function?
?function?
?function?
function
function
function

why the difference ?

Palaing

@Palaing

@rebolek Thank you! I thought cd was just an alias of change-dir

Boleslav Březovský

@rebolek

@Palaing You're welcome. It's almost alias. See that change-dir takes dir, but cd takes :dir, so it does not evaluate, OTOH you can do cd dir instead of cd %dir.

Vladimir Vasilyev

@9214

@cprinos difference stems from the fact that current compiler supports only a limited set of language, and cannot handle dynamic constructs such as in your example. Try to compile with -r -e flags instead.

lepinekong

@lepinekong_twitter

@Palaing I have developped cd which combines CD and @toomasv Tree here https://redlang.red/cd
and it works with variable and is tolerant with different file path format. So for example, you can try:
do https://redlang.red/cd
windows: c:\windows
cd windows
It works except it will print Tree twice a bug not a feature :)

dsunanda

@dsunanda

I am trying to create a PANEL with spacing of 0x0 - but the SPACE 0x0 seems to be ignored. In the code below, the red box has an OFFSET of 10x10. In R2 it would be 0x0. Any ideas, thanks?

unview/all
view/no-wait layout/tight [ 
    across space 0x0
    my-panel: panel [across space 0x0
          box 100x100 red  box 100x100 blue
          return
          box 100x100 pink box 100x100 green 
          ]
    ]
foreach box my-panel/pane [box/text: form box/offset show box]
do-events

Toomas Vooglaid

@toomasv

@dsunanda Add origin 0x0 to panel:

unview/all
view/no-wait layout/tight [ 
    across space 0x0
    my-panel: panel [origin 0x0 across space 0x0
          box 100x100 red  box 100x100 blue
          return
          box 100x100 pink box 100x100 green 
          ]
    ]
foreach box my-panel/pane [box/text: form box/offset show box]
do-events

dsunanda

@dsunanda

Perfect! Thanks!!

Max

@moliad

@lepinekong_twitter

@cprinos difference stems from the fact that current compiler supports only a limited set of language, and cannot handle dynamic constructs such as in your example. Try to compile with -r -e flags instead.

Is there some complete documentation about these differences? its a big deal for my project.

Vladimir Vasilyev

@9214

Not that I know of.

Max

@moliad

:sob:

Toomas Vooglaid

@toomasv

@dsunanda You are welcome!

Palaing

@Palaing

@lepinekong_twitter great! it does much more than I needed ;)

lepinekong

@lepinekong_twitter

@Palaing sure because I didn't do it for you but for me ;)

dsunanda

@dsunanda

Is there any way as yet to rotate an image? Perferably by an arbitrary number of degrees

Vladimir Vasilyev

@9214

@dsunanda matrix transformations. I'll let @toomasv to weight in, as he has some experience with that (and examples).

Toomas Vooglaid

@toomasv

@dsunanda There are three ways to rotate a figure:
rotate (takes also floats for angle):

t: 0 view [box 200x200 rate 10 draw [
    rotate 0 100x100 box 50x50 150x150
] on-time [face/draw/2: (t: t + 1) % 360]]

transform (takes also floats for angle):

t: 0 view [box 200x200 rate 10 draw [
    transform 100x100 0 1 1 0x0 box 50x50 150x150
] on-time [face/draw/3: (t: t + 1) % 360]]

and matrix:

t: 0 view [box 200x200 rate 10 draw [
    matrix [0 0 0 0 0 0] box -50x-50 50x50
] on-time [t: t + 1 face/draw/2: reduce [
    (cosine t) (negate sine t) (sine t) (cosine t) 100 100
]]]

lepinekong

@lepinekong_twitter

@toomasv great snippets thanks

Toomas Vooglaid

@toomasv

@lepinekong_twitter Thanks. Last one was not good -- too much copying. Here is better:

t: 0 view [
    box 200x200 rate 10 draw [matrix [0 0 0 0 100 100] box -50x-50 50x50] 
    on-time [t: t + 1 
        face/draw/2/1: cosine t
        face/draw/2/2: negate sine t
        face/draw/2/3: sine t
        face/draw/2/4: cosine t
]]

Toomas Vooglaid

@toomasv

Here is matrix rotation combined with scaling...:

t: 0 view [box 200x200 rate 10 draw [matrix [0 0 0 0 100 100] box -50x-50 50x50] 
    on-time [t: t + 1 
        face/draw/2/1: cosine t face/draw/2/2: 1.5 * negate sine t 
        face/draw/2/3: 1.5 * sine t face/draw/2/4: cosine t
]]

...skewing...:

t: 0 view [box 200x200 rate 10 draw [matrix [0 0 0 0 100 100] box -50x-50 50x50] 
    on-time [t: t + 1 
        face/draw/2/1: .5 * cosine t face/draw/2/2: negate sine t 
        face/draw/2/3: sine t face/draw/2/4: 1.5 * cosine t
]]

... and translation:

t: 0 view [box 200x200 rate 10 draw [matrix [0 0 0 0 100 80] box -50x-50 50x50] 
    on-time [t: t + 1 
        face/draw/2/1: cosine t face/draw/2/2: negate sine t face/draw/2/3: sine t 
        face/draw/2/4: cosine t face/draw/2/6: face/draw/2/6 + 10 - (t % 21)
]]

dsunanda

@dsunanda

Thanks for the rotation code - I'll have some fun playing with that soon.

Toomas Vooglaid

@toomasv

This is funnier "jumping square":

t: 0 view/tight [box 200x200 rate 10 draw [rotate 180 100x100 matrix [0 0 0 0 100 80] box -50x-50 50x50] 
    on-time [t: t + 1 
        face/draw/5/1: cosine t face/draw/5/2: negate sine t face/draw/5/3: sine t 
        face/draw/5/4: cosine t face/draw/5/6: face/draw/5/6 + 10 - (t % 21)
]]

lepinekong

@lepinekong_twitter

@toomasv clap!

GiuseppeChillemi

@GiuseppeChillemi

Hi,
if I have a function which accepts a block of block like:

blk: [[a] [b]]

and I want to include this data in a bigger block like:

blk2: [one [[a] [b]] two [[c][d]]]

And provide to the function a block of my choiche without picking (copying) it

If I move the index of the series to the block next to ONE

myblock: find/tail blk2 'one

>> probe myblock
= [[[a] [b]] two [[c][d]]]

I whish to

>> probe myblock
= [[a] [b]]

Without anything which involves a (memory) copy

Vladimir Vasilyev

@9214

@GiuseppeChillemi I don't follow, you want to select a block from another block?

GiuseppeChillemi

@GiuseppeChillemi

@9214 select involves a copy, I don't want to copy on selection, I which to access it like it is a: [[a] [b]]

*I wish

Vladimir Vasilyev

@9214

select involves a copy

No, it doesn't.

GiuseppeChillemi

@GiuseppeChillemi

no ?

I supposed it in rebol

Vladimir Vasilyev

@9214

>> block: [a [b c]]
== [a [b c]]
>> append select block 'a 'd
== [b c d]
>> block
== [a [b c d]]

GiuseppeChillemi

@GiuseppeChillemi

so, which is the difference between find/tail and select ?

Vladimir Vasilyev

@9214

I don't recall any series actions doing an explicit copying.

@GiuseppeChillemi select returns a value that follow the key (if any), find/tail searches for the first occurence of a value and returns a series past that value.

GiuseppeChillemi

@GiuseppeChillemi

From REBOL documentation: "Finds a value in the series and returns the value or series after it"
The word "returns" let me think about copying it.

Vladimir Vasilyev

@9214

>> select block 'a
== [b c d]
>> first find/tail block 'a
== [b c d]

@GiuseppeChillemi uhm, no. Again, there's no copying, you can check it yourself.

Where communities thrive

People

Repo info

Activity