red/help

For help with your code, suggestions and ideas, and learning Red.

GiuseppeChillemi

@GiuseppeChillemi

This message was deleted

if I have a function that accepts 2 arguments, is there a way to be them provided by the return value of a second one ?

Vladimir Vasilyev

@9214

@GiuseppeChillemi

>> foo: func [x y][x + y]
== func [x y][x + y]
>> bar: does [[1 2]]
== func [][[1 2]]
>> do head insert bar :foo
== 3

In general that would require apply, but you can use tricks similar to the above one.

dsunanda

@dsunanda

If you are happy to use an intermediate word to hold the two results, you can do it like below - using Vladimir's FOO and BAR functions

foo first x: bar x/2
== 3

GiuseppeChillemi

@GiuseppeChillemi

This message was deleted

Well, thanks, I was just imaging if there where a simple way to load code words/values at the current program execution position. So, it FOO expected X and Y then something like
(I assume "<" mean: "insert the result of the code between parens at this point")

FOO <(BAR)
Print "A"

Would be interpreted like

FOO 1 2
Print "A"

Vladimir Vasilyev

@9214

@GiuseppeChillemi compose or macros.

Vladimir Vasilyev

@9214

>> foo: func [x y][x + y]
== func [x y][x + y]
>> bar: does [[1 2]]
== func [][[1 2]]
>> compose [foo (bar)]
== [foo 1 2]
>> do compose [foo (bar)]
== 3

Macros is not what you want, I guess. They can't operate on values that are presented at run-time (i.e. you can't evaluate function bar, because it doesn't exist yet).

#do [bar: [1 2]]

#macro ['< paren!] func [start end][
    get in preprocessor/exec start/2/1 
]

probe expand [
    foo <(bar)
    foo #do keep [[1 2]]
]

GiuseppeChillemi

@GiuseppeChillemi

compose and macros are totally new for me.

dsunanda

@dsunanda

Vladimir mentioned APPLY. That's available in Rebol3, but noy (yet) in Red. If it worked in Red, then your code would simply be:

apply :foo bar

Vladimir Vasilyev

@9214

@GiuseppeChillemi a bit crazier version would be:

#macro [word! '< paren!] func [start end][
    reduce ['do 'compose reduce [start/1 end/-1]]
]

foo: func [x y][x + y]
bar: does [[1 2]]

probe foo <(bar)

dsunanda

@dsunanda

The good news is that APPLY is on Red's roadmap To-Do list. One day!

GiuseppeChillemi

@GiuseppeChillemi

This message was deleted

@dsunanda , which is the purpose of APPLY ?

dsunanda

@dsunanda

Basically to treat a block of values as if they were the args to a function. (the function is "applied" to the block). This link explains a bit more, with some examples. As it says: " there are times when you want to store the arguments as a single block and pass them to the function"

GiuseppeChillemi

@GiuseppeChillemi

@dsunanda thanks

Many things still to learn

REDBOL is a small giant universe.

dsunanda

@dsunanda

Lot's to learn - that makes it fun! You can fake up a cheap version of APPLY as below -- it won't handle /refinements:

apply: func [fun data /local blk][blk: copy [] append blk data insert blk 'fun do blk]
apply :foo bar  ;; as before

Vladimir Vasilyev

@9214

Or just

apply: func [function data][do compose [function (data)]]

>> apply: func [function data][do compose reduce [function quote (data)]]
== func [function data][do compose reduce [function quote (data)]]
>> apply 'reverse/part [[a b c d] 2]
== [b a c d]

Ungaretti

@Ungaretti

The predefined word what lists all predefined words of Red. Is there a way to list the words (variables) I created? In other words, to list Red's "dictionary"? Is calling that "dictionary" wrong?

Vladimir Vasilyev

@9214

@Ungaretti words-of system/words

Ungaretti

@Ungaretti

Boy you are fast!

Thanks.

Vladimir Vasilyev

@9214

@Ungaretti though, you'll need first to mark a "clean slate" point in this series. Even then you'll be able to track only words that have different spelling from the existing ones.

And it will track any words you've mentioned :wink:

>> skip tail words-of system/words -5
== [right-menu left-command right-command caps-lock num-lock]
>> 'abracadabra
== abracadabra
>> skip tail words-of system/words -5
== [left-command right-command caps-lock num-lock abracadabra]
>> [what? no this can't be serious!]
== [what? no this can't be serious!]
>> skip tail words-of system/words -5
== [what? this can't be serious!]

:point_up: note that no isn't among the last 5 "mentioned" words, because it was already pre-defined.

Vladimir Vasilyev

@9214

And, in general, you can't list all words you've created (by "created" I guess you mean setting word to some value in the form word: value), because they can be in local contexts / function's bodies.

I mean, you can, but that will require some grunt work.

Ungaretti

@Ungaretti

Interesting. I would like to understand how Red works internally, specially the (mechanism that looks like a) dictionary. Red stores the "links" between words and data. I can see how words are stored, but can't figure how it links them to, say, integers. This is not a question, don't bother explaining. Just wondering...

I guess I could list my variables with a combination of the code you posted plus get.

Vladimir Vasilyev

@9214

I would like to understand ... don't bother explaining

:confused:

Ungaretti

@Ungaretti

:smile: Just a wish for the future.

Vladimir Vasilyev

@9214

Red doesn't store links between words and data, it stores links between word and a "dictionary" where its value resides, and some additional info to fetch this value indirectly via link to a "dictionary".

Ungaretti

@Ungaretti

I want to save your time for my more important questions.

So there is something inside that may be called a "dictionary"! Good to know.

Vladimir Vasilyev

@9214

It's called a context.

Ungaretti

@Ungaretti

Isn't context a fancy word for object?

Vladimir Vasilyev

@9214

@Ungaretti nope. Objects provide a context, but they are not contexts themselves.

Functions, when you call them, provide contexts too.

Ungaretti

@Ungaretti

I got it wrong then. Have to check my notes. But isn't make object!,context and object pretty much the same?

I mean, as commands?

Vladimir Vasilyev

@9214

@Ungaretti context is a wrapper around make object!:

>> source context
context: func ["Makes a new object from an evaluated spec" 
    spec [block!]
][
    make object! spec
]

object is a... well, see yourself :wink:

Ungaretti

@Ungaretti

@9214 Thanks once more!

Wait, it says there object: :context, so they are the same?

Vladimir Vasilyev

@9214

>> same? :object :context
== true

Ungaretti

@Ungaretti

Aha!

Where communities thrive

People

Repo info

Activity